#!/usr/local/bin/xcerpt --cgi
%+ DOC COMMENT BEGIN
%  This Xcerpt program reformats the information contained in the RSS summary 
%  of the Tagesschau website, the most popular news broadcast in German TV.
%+ DOC COMMENT END

GOAL
    out {
      resource { "stdout:", "xml" },
      html [
        head [ title [ "Tagesschau: Schlagzeilen" ] ],
        body [
          div [ i [ "This document is generated dynamically by ", 
	            a [ attributes { href {"http://cvs.wastl.net/XcerptData/rss/xcerpt/rule-RSS-Tagesschau.xcerpt"} }, "rule-RSS-Tagesschau.xcerpt"], 
	            " from the RSS use case."] ],
          var Channel
        ]
      ]
    }
FROM
    var Channel -> div {{ attributes {{ id { "channel" } }} }}
END


CONSTRUCT
    div [
      attributes { id { "channel" } },
      h1 [ "Channel:", var Channel ],
      table [
        all [
          tr [
            attributes { style { "background-color: lightblue"} },
            td [
              attributes { style { "font-weight:bold; font-family: Arial,Helvetica"} },
              var Title
            ]
          ],
          tr [
            td [
              var Description, br {}, 
              a [ attributes { href { var Link } }, "Mehr ..."]
            ]
          ]
        ]
      ]
    ]
FROM
    ns-default = "http://my.netscape.com/rdf/simple/0.9/"
    ns-prefix rdf = "http://www.w3.org/1999/02/22-rdf-syntax-ns#"
    in {
      resource { "http://www.tagesschau.de/xml/tagesschau-newsticker/", "xml" },
      rdf:RDF [[
        channel [[
          title [[
            var Channel
          ]]
        ]],
        item [[
          title [[
            var Title
          ]],
          link [[
            var Link
          ]],
          description [[
            var Description
          ]]
        ]]
      ]]
    }
END